;***************************edit_1.asm******************************
;
					extend
;
				include 	label
				include     label_3
;--------------------------------------------------------------------
;(INITIAL)
				ext		INIT_SET,Z_SET1,CHARA_SET,POINT_SET8
				ext		SC_SET,OBJ_SET,OAM_SET,COWD_SET,BG2_CHRSET
				ext		SC2_SET,VRAM_TENSOU,SC1_SET,VRAMZ_SET
				ext		INIDOS_SET,DOS_Entry,DSFN_SET,SUM_CHECK1
				ext		Decode_M3,CG1_SET
;-------------------------------------------------------------------
;(MAIN)
				ext		TRG_set,MODECHG_SET,POSI_MOVE,POSDSP_SET
				ext		AREA_SET,ERSAREA_SET,POSI_MOVE,POSDSP_SET,FILE_SET1
				ext		NUM_SET,POSI_MOVE1,POSDSP_SET1,POINT_SET,SPEED_SET
				ext		ERASE_SET,S.LMODE_SET,SAVE_CHK,SAVE_SET,MENU_SET
				ext		LOAD_SET,CLEAR_SET,END_SET,slelct_edit,NOW_DSP4
				ext		KASOL_FLASH1
;-------------------------------------------------------------------------
;(NMI)
				ext	    NMI_SET
;------------------------------------------------------------
				ext		FADEIN_SET,fadein_set
;
				glb		ED_init_1,ED_main_1,ED_nmi_1
;
				glb		AREA_DEIT,CODE_EDIT,POINT_EDIT
				glb		MOVE_SET,FADE_IN

;-----------------------------------------------------------------------
editer		sect	rel			;(10 PBR)
;
;=====================================================================
ED_init_1		equ		$
				phb
				phk
				plb
;-------------------------------------
				mem8
				idx8
				sep		#00110000b
;
				sei
				stz		!420bh
				stz		!420ch
;-------------------------------------
;(NOT USE "../JOIN")
;				cop		00h				;dos stop set.
;				jsr     POINT_SET8		;stak buffer change.
;- - - - - - - - - - - - - - - - - - - - - - - 
				mem16
				idx16
				rep		#00110000b
				JSL		>Decode_M3
				mem8
				idx8
				sep     #00110000b
				JSR		INIT_SET
				JSR		VRAMZ_SET
;
				JSR		Z_SET1			;BG1		
;				JSR		CHARA_SET		;to Vram set.
				JSR		SC1_SET			;to Vram set.
				JSR		SC_SET			;to buffer set.
				JSR		OBJ_SET	
				JSR		OAM_SET
				JSR		CG1_SET
;
				JSR		COWD_SET		;HDMA(color window)
;
				JSR		BG2_CHRSET		;BG2, to vram set.
				JSR		SC2_SET			;to buffer set.
				JSR		VRAM_TENSOU		;to Vram set(sc2).
				JSR		DSFN_SET		;dos file name set.
;				JSR		SUM_CHECK1		;back up sum check.
;- - - - - - - - - - - - - - - - - - - 
;(NOT USE "../JOIN")
;				JSL		>DOS_Entry		;sfx_dos set.
;				JSR		INIDOS_SET		;dos initial set.
;-------------------------------------
				mem16
				idx16
				rep		#00110000b
;-------------------------------------
				plb
				rtl
;
;
;=============================================
ED_main_1		equ		$
				phb
				phk
				plb
;-------------------------------------------
				idx8
				mem8
				sep		#00110000b
;-------------------------------------------
				lda		32h
				bne		end_mainroitine
				ldx		fade_mode
				jmp		(!fadein_set,x)
;-------------------------------------------
MOVE_SET		jsr     TRG_set
				jsr		KASOL_FLASH1
				jsr     MODECHG_SET
				jmp		(!slelct_edit,x)
;-------------------------------------------
AREA_DEIT		jsr		POSI_MOVE		;set mode
				jsr		POSDSP_SET
				jsr		AREA_SET
				jsr		ERSAREA_SET
				jmp		S.L_EDIT
;---------------------------------------------
CODE_EDIT		jsr		POSI_MOVE
				jsr		POSDSP_SET
				jsr     NUM_SET
				jmp		S.L_EDIT
;---------------------------------------------
POINT_EDIT		jsr		POSI_MOVE1
				jsr		POSDSP_SET1
				JSR		POINT_SET
				jsr		SPEED_SET
				JSR		ERASE_SET
				jmp		S.L_EDIT
;---------------------------------------------
S.L_EDIT		jsr		S.LMODE_SET		;s.l mode 
				jsr		MENU_SET
				jsr		FILE_SET1
;
				jsr		SAVE_CHK
				jsr		SAVE_SET
				jsr		LOAD_SET
				jsr		CLEAR_SET
				jmp		end_mainroitine
;----------------------------------------------
FADE_IN			JSR		FADEIN_SET
;----------------------------------------------
end_mainroitine	mem16
				idx16
				rep		#00110000b
				plb
				rtl
;==================================================
ED_nmi_1		equ		$
				phb
				phk
				plb
;----------------------------------------------
				mem8
				idx8
				sep		#00110000b	
				lda		32h
				bne		owari_nmi			
;----------------------------------------------
				JSR     NMI_SET
;----------------------------------------------
owari_nmi		mem16
				idx16
				rep		#00110000b
;----------------------------------------------
				plb
				rtl
				END