POCHIIN		EQU	$
		JSR	POCHIDASHIN
;
		RTL
;
;
;------------------------------------------------------------------------
;-	move (POCHI)							-
;------------------------------------------------------------------------
POCHIMV		EQU	$
		JSL	>ENMDCK			; mode check
;
		LDY	!ECRSFG,X
		DEY
		BEQ	POCMV0020		; baby hit ? [yes->POCMV0020]
		BMI	POCMV0020		; enemy hit ? [no->POCMV0020]
;
		LDA	!ENWRK8,X
		STA	<EWORK
		CPY	<EWORK
		BEQ	POCMV0010		; jyare enmy ? [yes->POCMV0010]
;
		LDA	!ENSHOT,Y
		BEQ	POCMV0020		; shot ? [no->POCMV0020]
;
POCMV0010	EQU	$
		LDA	#0FD00H
		STA	!ENYSPD,Y
		LDA	#00040H
		STA	!ENGPOW,Y
		PHY
		LDA	!ECROSX,Y
		AND	#08000H
		ASL	A
		ROL	A
		ASL	A
		TAY
		LDA	POCHANSYAMINX,Y
		PLY
		STA	!ENXSPD,Y
POCMV0020	EQU	$
		LDA	!ENCBFG,X
		AND	#00001H
		BNE	POCMV0040		; ashi atari ? [yes->POCMV0040]
;
		LDA	!ENXPOW,X
		PHA
		STZ	!ENXPOW,X
		JSR	POCHIJUMP
;
		PLA
		STA	!ENXPOW,X
		BRA	POCMV00F0
;
POCMV0040	EQU	$
		JSR	POCHISHOTENSH
;
		LDA	<ENCONT,X
		TAX
		JSR	(POCHISEL,X)
;
POCMV00F0	EQU	$
		JMP	>EPCRCK
;
;
POCHISEL	EQU	$
		WORD	POCHIDASH
		WORD	POCHISTOP
		WORD	POCHITURN
		WORD	POCHIJYARE
		WORD	POCHIAKIRAME
;
POCHIDASHIN	EQU	$
		LDX	<ENINDX
		LDA	#pochidash
		STA	<ENCONT,X
		LDA	#pochiruntm
		STA	!ENTIM0,X
		LDY	!ENMUKI,X
		LDA	POCHIMAXX,Y
		STA	!ENXMAX,X
		LDA	#00080H
		STA	!ENXPOW,X
		LDA	POCHIXSPD,Y
		STA	!ENXSPD,X
		STA	!ENWRK2,X		; x speed cheack ram
		LDA	POCHIDASHPT
		AND	#000FFH
		STA	!ENCHPT,X
		RTS
;
;
POCHIDASH	EQU	$
		LDX	<ENINDX
		LDY	!ENWRK8,X
		BEQ	POCDSH0010		; enemy index on ? [no->POCDSH0010]
;
		LDA	!ECENTX,X
		SEC
		SBC	!ECENTX,Y
		STA	<EWORK
		AND	#08000H
		ASL	A
		ROL	A
		ASL	A
		EOR	!ENMUKI,X
		BNE	POCDSH0018		; turn ? [yes->POCDSH0018]
;
		LDA	<EWORK
		ABS16
		CMP	#pochitamago0
		BCS	POCDSH0030		; area in ? [no->POCDSH0030]
;
		BRA	POCDSH0028
;
POCDSH0010	EQU	$
		LDA	!EPXMUK,X
		AND	#000FFH
		EOR	!ENMUKI,X
		BEQ	POCDSH0020		; player back [no->POCDSH0020]
;
POCDSH0018	EQU	$
		STZ	!ENXMAX,X
		LDA	#00080H
		STA	!ENXPOW,X
		LDA	#02
		STA	<ENWRK0,X
		LDA	#pochi06
		STA	!ENCHPT,X
		LDA	#pochistop
		STA	<ENWRK4,X
		JMP	POCHITURNIN		; player back [yes->POCHITURNIN]
;
POCDSH0020	EQU	$
		JSR	POCHIBGCK		; jump check !!
;
		LDA	#pochiwidarea
		STA	<EWORK
		ASL	A
		STA	<EWORK2
		JSR	POCHIPLSH
;
		BCC	POCDSH0028		; area in ? [yes->POCDSH0028]
;
;;;;;;;;		CPX	!PLNAGE_IX
;;;;;;;;		BNE	POCDSH0030		; target ? [no->POCDSH0030]
		LDA	!PLNAGE
		BEQ	POCDSH0030		; player nage ? [no->POCDSH0030]
;
POCDSH0028	EQU	$
		STZ	!ENXMAX,X
		LDA	#00040H
		STA	!ENXPOW,X
		LDA	!ENXSPD,X
		BEQ	POCHISTOPIN		; stop ? [yes->POCHISTOPIN]
;
		EOR	!ENWRK2,X
		BMI	POCHISTOPIN		; stop ? [yes->POCHISTOPIN]
;
		BRA	POCDSH0038
;
POCDSH0030	EQU	$
		LDY	!ENMUKI,X
		LDA	POCHIMAXX,Y
		STA	!ENXMAX,X
		LDA	#00080H
		STA	!ENXPOW,X
POCDSH0038	EQU	$
		LDA	!ENTIM0,X
		BNE	POCDSH0100		; pattern change ? [no->POCDSH0100]
;
		LDA	<ENWRK0,X
		INC	A
		CMP	#04
		BCC	POCDSH0040		; [->POCDSH0040]
;
		LDA	#00
POCDSH0040	EQU	$
		STA	<ENWRK0,X
		TAY
		LDA	POCHIDASHPT,Y
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	!ENXSPD,X
		ABS16
		XBA
		AND	#00003H
		TAY
		LDA	POCHIRUNTM,Y
		AND	#000FFH
		STA	!ENTIM0,X
POCDSH0100	EQU	$
		RTS
;
;
POCHISTOPIN	EQU	$
		LDX	<ENINDX
		LDA	#pochistop
		STA	<ENCONT,X
		STZ	<ENWRK0,X
		STZ	!ENXPOW,X
		STZ	!ENXSPD,X
		LDA	POCHISTOPPT
		AND	#000FFH
		STA	!ENCHPT,X
;;;;;;;;		CPX	!PLNAGE_IX
;;;;;;;;		BEQ	POCSTPIN0070		; target ? [yes->POCSTPIN0070]
		LDA	!PLNAGE
		BNE	POCSTPIN0070		; player nage ? [yes->POCSTPIN0070]
;
		LDA	#pochistptm
		BRA	POCSTPIN0080
;
POCSTPIN0070	EQU	$
		LDA	#pochistptm2
POCSTPIN0080	EQU	$
		STA	!ENTIM0,X
		RTS
;
;
POCHISTOP	EQU	$
		LDX	<ENINDX
;;;;;;;;		CPX	!PLNAGE_IX
;;;;;;;;		BNE	POCSTP0004		; target ? [yes->POCSTP0004]
		LDA	!PLNAGE
		BEQ	POCSTP0004		; player nage ? [yes->POCSTP0004]
;
		JMP	POCSTP0030		; target ? [no->POCSTP0030]
;
POCSTP0004	EQU	$
		LDY	!ENWRK8,X
		BEQ	POCSTP0010		; enemy index on ? [no->POCSTP0010]
;
		LDA	!ECENTX,X
		SEC
		SBC	!ECENTX,Y
		STA	<EWORK
		AND	#08000H
		ASL	A
		ROL	A
		ASL	A
		EOR	!ENMUKI,X
		BNE	POCSTP0018		; turn ? [yes->POCSTP0018]
;
		LDA	<EWORK
		ABS16
		CMP	#pochitamago1
		BCC	POCSTP0008		; aria in ? [yes->POCSTP0008]
;
		JMP	POCHIDASHIN
;
POCSTP0008	EQU	$
		LDA	#pochijyare
		STA	<ENCONT,X
		JMP	JYAREMDSET
;
POCSTP0010	EQU	$
		LDA	!EPXMUK,X
		AND	#000FFH
		EOR	!ENMUKI,X
		BEQ	POCSTP0020		; player back [no->POCSTP0020]
;
POCSTP0018	EQU	$
		LDA	#01
		STA	<ENWRK0,X
		LDA	#pochi11
		STA	!ENCHPT,X
		LDA	#pochiturntm
		STA	!ENTIM0,X
		LDA	#pochistop
		STA	<ENWRK4,X
		BRA	POCHITURNIN		; player back [yes->POCHITURNIN]
;
POCSTP0020	EQU	$
		LDA	#pochiwidarea2
		STA	<EWORK
		ASL	A
		STA	<EWORK2
		JSR	POCHIPLSH
;
;;;;;;;;		BCC	POCSTP0030		; area in ? [yes->POCSTP0030]
		BCS	POCSTP0028		; area in ? [no->POCSTP0028]
;
		LDA	<EWORK8
		BMI	POCSTP0030		; [->POCSTP0030]
;
		CMP	#00030H
		BCC	POCSTP0030		; [->POCSTP0030]
;
		CMP	#00060H
		BCS	POCSTP0028		; [->POCSTP0028]
;
		LDA	#pochijumpspd
		STA	!ENYSPD,X
		LDA	#pochi03
		STA	!ENCHPT,X
		RTS
;
;
POCSTP0028	EQU	$
;;;;;;;;		CPX	!PLNAGE_IX
;;;;;;;;		BEQ	POCSTP0030		; target ? [yes->POCSTP0030]
		LDA	!PLNAGE
		BNE	POCSTP0030		; player nage ? [yes->POCSTP0030]
;
		JMP	POCHIDASHIN
;
;
POCSTP0030	EQU	$
		LDA	!ENTIM0,X
		BNE	POCSTP0100		; pattern change ? [no->POCSTP0100]
;
		LDA	<ENWRK0,X
		INC	A
		CMP	#04
		BCC	POCSTP0040		; [->POCSTP0040]
;
		LDA	#00
POCSTP0040	EQU	$
		STA	<ENWRK0,X
		TAY
		LDA	POCHISTOPPT,Y
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	!BERFLG
		BNE	POCSTP0060		; bero on ? [yes->POCSTP0060]
;
		LDA	!EATSTP
		BNE	POCSTP0070		; now eating ? [yes->POCSTP0070]
;
POCSTP0060	EQU	$
;;;;;;;;		CPX	!PLNAGE_IX
;;;;;;;;		BNE	POCSTP0080		; target ? [no->POCSTP0080]
		LDA	!PLNAGE
		BEQ	POCSTP0080		; player nage ? [no->POCSTP0080]
;
POCSTP0070	EQU	$
		LDA	#pochistptm2
		BRA	POCSTP0088
;
POCSTP0080	EQU	$
		LDA	#pochistptm
POCSTP0088	EQU	$
		STA	!ENTIM0,X
POCSTP0100	EQU	$
		RTS
;
;
POCHIINSEL	EQU	$
		WORD	POCHIDASHIN
		WORD	POCHISTOPIN
		WORD	POCHITURNIN
		WORD	JYAREMDSET
		WORD	POCHIAKIRAMEIN
;
POCHITURNIN	EQU	$
		LDX	<ENINDX
		LDA	#pochiturn
		STA	<ENCONT,X
		RTS
;
;
POCHITURN	EQU	$
		LDX	<ENINDX
		LDA	<ENWRK0,X
		CMP	#02
		BNE	POCTRN0080		; xspeed chack ? [no->POCTRN0080]
;
		LDA	!ENXSPD,X
		BEQ	POCTRN0040		;
;
		EOR	!ENWRK2,X
		BPL	POCTRN01F0		;
;
		STZ	!ENXSPD,X
POCTRN0040	EQU	$
		STZ	!ENXPOW,X
		LDA	#pochiturntm
		STA	!ENTIM0,X
		LDA	#pochi11
		STA	!ENCHPT,X
		DEC	<ENWRK0,X
;
POCTRN0080	EQU	$
		LDA	!ENTIM0,X
		BNE	POCTRN01F0		; pattern change ? [no->POCTRN01F0]
;
		LDA	<ENWRK0,X
		BNE	POCTRN0100		; next mode ? [no->POCTRN0100]
;
		LDA	<ENWRK4,X
		TAX
		JMP	(POCHIINSEL,X)
;
;
POCTRN0100	EQU	$
		LDA	!ENMUKI,X
		EOR	#02
		STA	!ENMUKI,X
		LDA	#pochiturntm
		STA	!ENTIM0,X
		DEC	<ENWRK0,X
POCTRN01F0	EQU	$
		RTS
;
;
POCHIJUMP	EQU	$
		LDA	!ENYSPD,X
		CLC
		ADC	#pochiytop
		CMP	#pochiytop*2
		BCS	POCJMP0040		; top point ? [no->POCJMP0040]
;
		LDA	#pochi04
		BRA	POCJMP0100
;
POCJMP0040	EQU	$
		LDA	!ENYSPD,X
		BPL	POCJMP0080		; down ? [yes->POCJMP0080]
;
		LDA	#pochi03
		BRA	POCJMP0100
;
POCJMP0080	EQU	$
		LDA	#pochi05
POCJMP0100	EQU	$
		STA	!ENCHPT,X
		RTS
;
;
POCHIJYARE	EQU	$
		LDX	<ENINDX
;;;;;;;;		CPX	!PLNAGE_IX
;;;;;;;;		BNE	POCJYA0040		; target ? [no->POCJYA0040]
		LDA	!PLNAGE
		BEQ	POCJYA0040		; player nage ? [no->POCJYA0040]
;
		LDA	!EPXMUK,X
		AND	#000FFH
		EOR	!ENMUKI,X
		BNE	POCJYA0120		; player back ? [yes->POCJYA0120]
;
		JMP	POCHISTOPIN
;
POCJYA0040	EQU	$
		LDA	!ENWRK8,X
		BEQ	POCJYA0080		; enemy index on ? [no->POCJYA0080]
;
		LDA	!ENDSXL,X
		CLC
		ADC	#00008H
		ORA	!ENDSYL,X
		AND	#0FF00H
		BEQ	POCJYA0100		; display out ? [no->POCJYA0100]
;
		STZ	!ENWRK8,X
POCJYA0080	EQU	$
		JMP	POCHIDASHIN
;
POCJYA0100	EQU	$
		LDA	!ECENTX,X
		SEC
		SBC	!ECENTX,Y
		STA	<EWORK
		AND	#08000H
		ASL	A
		ROL	A
		ASL	A
		EOR	!ENMUKI,X
		BEQ	POCJYA0140		; turn ? [no->POCJYA0140]
;
POCJYA0120	EQU	$
		LDA	#01
		STA	<ENWRK0,X
		LDA	#pochi11
		STA	!ENCHPT,X
		LDA	#pochiturntm
		STA	!ENTIM0,X
		LDA	#pochistop
		STA	<ENWRK4,X
		JMP	POCHITURNIN
;
POCJYA0140	EQU	$
		LDA	<EWORK
		ABS16
		CMP	#pochitamago1
		BCS	POCJYA0080		; aria out ? [yes->POCJYA0080]
;
		LDA	!ECENTY,X
		SEC
		SBC	!ECENTY,Y
		CLC
		ADC	#pochitamago2
		CMP	#pochitamago2*2
		BCS	POCJYA0080		; aria out ? [yes->POCJYA0080]
;
		LDA	<ENWRK4,X
		TAX
		JMP	(POCHIJYARESEL,X)
;
;
POCHIJYAREINSEL	EQU	$
		WORD	POCHIJYAR1IN
		WORD	POCHIJYAR2IN
		WORD	POCHIJYAR2IN
		WORD	POCHIJYAR4IN
;
POCHIJYARESEL	EQU	$
		WORD	POCHIJYAR1
		WORD	POCHIJYAR2
		WORD	POCHIJYAR2
		WORD	POCHIJYAR4
;
POCHIJYAR1IN	EQU	$
		LDX	<ENINDX
		STZ	<ENWRK0,X
		LDA	POCHIJYAR1PT
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	#pochijyare1tm
		STA	!ENTIM0,X
		RTS
;
;
POCHIJYAR1	EQU	$
		LDX	<ENINDX
		LDA	!ENTIM0,X
		BNE	POCJ100F0		; pattern change ? [no->POCJ100F0]
;
		LDA	<ENWRK0,X
		INC	A
		CMP	#pochijyare1ptn
		BCS	POCJ10100		; next mode ? [yes->POCJ10100]
;
		STA	<ENWRK0,X
		TAY
		LDA	POCHIJYAR1PT,Y
		AND	#000FFH
		STA	!ENCHPT,X
		CPY	#06
		BNE	POCJ10080		; [->POCJ10080]
;
		LDY	!ENWRK8,X
		LDA	#tamagobound
		STA	!ENYSPD,Y
		LDA	#00040H
		STA	!ENGPOW,Y
		LDA	#01
		STA	!ENSHOT,Y
POCJ10080	EQU	$
		LDA	#pochijyare1tm
		STA	!ENTIM0,X
POCJ100F0	EQU	$
		RTS
;
;
POCJ10100	EQU	$
		JMP	JYAREMDSET		; next jyare mode set !!
;
POCHIJYAR2IN	EQU	$
		LDX	<ENINDX
		STZ	<ENWRK0,X
		LDA	POCHIJYAR2PT
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	#pochijyare2tm
		STA	!ENTIM0,X
		LDA	#pochijyare2pt2
		STA	!ENWRK6,X
		RTS
;
;
POCHIJYAR2	EQU	$
		LDX	<ENINDX
		LDA	!ENTIM0,X
		BNE	POCJ200F0		; pattern change ? [no->POCJ200F0]
;
		LDA	<ENWRK0,X
		INC	A
		CMP	#pochijyare2ptn
		BCC	POCJ20040		; [->POCJ20040]
;
		DEC	!ENWRK6,X
		BEQ	POCJ10100		; next mode ? [yes->POCJ10100]
;
		LDA	#00
POCJ20040	EQU	$
		STA	<ENWRK0,X
		TAY
		LDA	POCHIJYAR2PT,Y
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	#pochijyare2tm
		STA	!ENTIM0,X
POCJ200F0	EQU	$
		RTS
;
;
POCHIJYAR3IN	EQU	$
		LDX	<ENINDX
		LDA	#pochijyare3ptn
		STA	!ENWRK6,X
POCJ3IN0040	EQU	$
		STZ	<ENWRK0,X
		LDY	!ENMUKI,X
		LDA	POCHIJ3XSPD,Y
		STA	!ENXSPD,X
		LDA	#pochijyare3jmp
		STA	!ENYSPD,X
		RTS
;
;
POCHIJYAR3	EQU	$
		LDX	<ENINDX
		LDA	!ENTIM0,X
		BEQ	POCJYAR_3		; pattern change ? [yes->POCJYAR_3]
;
		RTS
;
;
POCJYAR_3	EQU	$
		LDA	<ENWRK0,X
		TAX
		JMP	(PCJY3SEL,X)
;
PCJY3SEL	EQU	$
		WORD	POCJ30000
		WORD	POCJ30100
		WORD	POCJ30200
;
POCJ30000	EQU	$
		LDX	<ENINDX
		LDA	#pochiturntm
		STA	!ENTIM0,X
		LDA	#pochi11
		STA	!ENCHPT,X
		INC	<ENWRK0,X
		INC	<ENWRK0,X
		RTS
;
;
POCJ30100	EQU	$
		LDX	<ENINDX
		LDA	#pochiturntm
		STA	!ENTIM0,X
		LDA	!ENMUKI,X
		EOR	#02
		STA	!ENMUKI,X
		INC	<ENWRK0,X
		INC	<ENWRK0,X
		RTS
;
;
POCJ30200	EQU	$
		LDX	<ENINDX
		JMP	POCJ3IN0040
;
;
POCHIJYAR4IN	EQU	$
		LDX	<ENINDX
		LDA	#pochijyare4pt2
		STA	!ENWRK6,X
		RTS
;
;
POCHIJYAR4	EQU	$
		LDX	<ENINDX
		LDA	!ENTIM0,X
		BNE	POCJ400F0		; pattern change ? [no->POCJ400F0]
;
		LDA	<ENWRK0,X
		INC	A
		CMP	#pochijyare4ptn
		BCC	POCJ40080		; pattern max ? [no->POCJ40080]
;
		DEC	!ENWRK6,X
		BEQ	POCJ40100		; next mode ? [yes->POCJ40100]
;
		LDA	#00
POCJ40080	EQU	$
		STA	<ENWRK0,X
		TAY
		LDA	POCHISTOPPT,Y
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	#pochistptm2
		STA	!ENTIM0,X
POCJ400F0	EQU	$
		RTS
;
;
POCJ40100	EQU	$
		JMP	JYAREMDSET		; next jyare mode set !!
;
;
JYAREMDSET	EQU	$
		JSL	>RANDAM
;
		LDA	<RANDM0
		AND	#00006H
		STA	<ENWRK4,X
		TAX
		JMP	(POCHIJYAREINSEL,X)
;
;
POCHIAKIRAMEIN	EQU	$
		LDX	<ENINDX
		LDA	#pochi00
		STA	!ENCHPT,X
		LDA	POCHIAKIRAMETM
		STA	!ENTIM0,X
		STZ	<ENWRK0,X
		RTS
;
;
POCHIAKIRAME	EQU	$
		LDX	<ENINDX
		LDA	!ENTIM0,X
		BNE	POCATR00F0		; pattern change ? [no->POCATR00F0]
;
		LDA	<ENWRK0,X
		INC	A
		CMP	#13
		BCC	POCATR0080		; [->POCATR0080]
;
POCATR0080	EQU	$
		STA	<ENWRK0,X
		TAY
		LDA	POCHIAKIRAMEPT,Y
		AND	#000FFH
		STA	!ENCHPT,X
		LDA	POCHIAKIRAMETM,Y
		AND	#000FFH
		STA	!ENTIM0,X
		TYA
		AND	#00003H
		CMP	#00003H
		BNE	POCATR00A0		; flip ? [no->POCATR00A0]
;
		LDA	!ENMUKI,X
		EOR	#02
		STA	!ENMUKI,X
POCATR00A0	EQU	$
POCATR00F0	EQU	$
		RTS
;
;
POCHIBGCK	EQU	$
		LDY	!ENMUKI,X
		LDA	!ENCBFG,X
		AND	POCHIYOKOATARI,Y
		BNE	POCBGCK0080		; yoko atari ? [yes->POCBGCK0080]
;
		LDA	!ECENTX,X
		CLC
		ADC	POCHIYOKOATARI2,Y
		STA	R8
		LDA	!ECENTY,X
		STA	R0
		PHX
		M_CHIPR	M_BGUNIT_READ
		PLX
;
		LDA	R5
		BEQ	POCBGCK0100		; yoko atari ? [no->POCBGCK0100]
;
POCBGCK0080	EQU	$
		LDA	#pochijumpspd
		STA	!ENYSPD,X
		LDA	#pochi03
		STA	!ENCHPT,X
		PLA
POCBGCK0100	EQU	$
		RTS
;
;
POCHISHOTENSH	EQU	$
		TXA
		STA	R1
		PHX
		M_CHIP	SHOTENSR
;
		PLX
		LDA	!ENWRK8,X
		STA	<EWORK
		LDY	R1
		BMI	PSESH00F0		; shot on ? [no->PSESH00F0]
;
		CPY	<EWORK
		BEQ	PSESH00F0		; [->PSESH00F0]
;
		LDA	!ENMYNO,Y
		CMP	#EGG00
		BMI	PSESH00F0		; egg ? [no->PSESH00F0]
;
		CMP	#EGG09+1
		BPL	PSESH00F0		; egg ? [no->PSESH00F0]
;
		TYA
		AND	#000FFH
		STA	!ENWRK8,X
PSESH00F0	EQU	$
		LDY	!ENWRK8,X
		BEQ	PSESH00F8		; enemy index on ? [no->PSESH00F8]
;
		LDA	!ENMODE,Y
		CMP	#EMOVE
		BNE	PSESH00F6		; move ? [no->PSESH00F6]
;
		LDA	!ENMYNO,Y
		CMP	#EGG00
		BCC	PSESH00F6		; egg ? [no->PSESH00F6]
;
		CMP	#EGG09+1
		BCS	PSESH00F6		; egg ? [no->PSESH00F6]
;
		LDA	!ENWRK4,Y
		BNE	PSESH00F6		; player kobun ? [yes->PSESH00F6]
;
		LDA	!ENMODE,Y
		CMP	#EEATM
		BNE	PSESH00F8		; eat mode ? [no->PSESH00F8]
;;;;;;;;		BEQ	PSESH00F6		; eat mode ? [yes->PSESH00F6]
;;;;;;;;;
;;;;;;;;		LDA	!ENDSXL,Y
;;;;;;;;		CLC
;;;;;;;;		ADC	#00008H
;;;;;;;;		ORA	!ENDSYL,Y
;;;;;;;;		AND	#0FF00H
;;;;;;;;		BEQ	PSESH00F8		; display in ? [yes->PSESH00F8]
;
PSESH00F6	EQU	$
		STZ	!ENWRK8,X
PSESH00F8	EQU	$
		RTS
;
;
;--------------------------------------------------------
;-	EWORK <- x hankei				-
;-	EWORK2 <- x width				-
;--------------------------------------------------------
POCHIPLSH	EQU	$
		LDA	!ECENTY,X
		SEC
		SBC	!PCENTY
		STA	<EWORK8
		LDA	!ECENTX,X
		SEC
		SBC	!PCENTX
		PHA
		ABS16
		STA	<EWORK4			; x kyori save !!
		PLA
		CLC
		ADC	<EWORK
		CMP	<EWORK2
		BCS	PPSH0100		; aria in ? [no->PPSH0100]
;
		LDA	<EWORK4
		ASL	A
		STA	<EWORK6
		LDA	<EWORK8
		CLC
		ADC	<EWORK4
		CMP	<EWORK6
		BCC	PPSH0100		; aria in ? [yes->PPSH0100]
;
		LDA	<EWORK8
		CLC
		ADC	#pochiunderarea
		BPL	PPSH0080		; area in ? [yes->PPSH0080]
;
		SEC
		BRA	PPSH0100
;
PPSH0080	EQU	$
		CLC
PPSH0100	EQU	$
		RTS
;
;