;
		INCLUDE	zel_ram.asm
;
;------------------------------------------------------------------------
;
;		PAL_ZELDA-3 (GERMAN)		1992.05.06(WED)
;
;------------------------------------------------------------------------
;
		ORG	07FF50H
;
;=============================================== (zel_sub3) =============
		GLB	SWYKCNG0,SWYKCNG
;
		GLB	MPDP900,MPDPC00
;========================================================================
		EXT	bgw18
;
		EXT	BLANKING,LGTWPMV
;========================================================================
;
		EXTEND
		MEM8
		IDX8
;
;
;
;************************************************************************
;*		Swich-yuka change			(SWYKCNG)	*
;************************************************************************
SWYKCNG0	EQU	$
		STZ	!SWYKPT
SWYKCNG		EQU	$
		IDX16
		REP	#00010000B	; index 16bit mode
;
		LDX	#00020H*0
		LDY	#00020H*1
		LDA	!SWYKPT
		BEQ	SWCN20		;
;					;
		TYX
		LDY	#00020H*0
SWCN20		EQU	$
		STY	<WORKE
;
		PHB
		LDA	#BANK RSETCBF
		PHA
		PLB			; (DBR) set
;
		MEM16
		REP	#00100000B	; memory 16bit mode
;
		LDY	#00000H
SWCN100		EQU	$
		LDA	>SWYCHBF,X
		STA	RSETCBF,Y
		INX
		INX
		INY
		INY
		CPY	#00020H*1
		BNE	SWCN100		;
;					;
		LDX	<WORKE
SWCN140		EQU	$
		LDA	>SWYCHBF,X
		STA	RSETCBF,Y
		INX
		INX
		INY
		INY
		CPY	#00020H*2
		BNE	SWCN140		;
;					;
		MEM8
		IDX8
		SEP	#00110000B	; memory,index 8bit mode
;
		PLB			; (DBR) pull
;
		LDA	#bgw18
		STA	<BGWTFG
KAGEI80		EQU	$
		RTL
;
;
;
;
;
;
;---------------------------------------; fade out
MPDP900		EQU	$
		DEC	<BLKFLG
		BNE	MPDP980		; fade out ?
;					; yes
		JSL	>BLANKING	; blanking on & H-DMA disable
;// 03.09.17 //		LDA	#10000000B
;// 03.09.17 //		STA	2100H
;// 03.09.17 //		STA	<BLKFLG		; blanking on
		INC	!MAPDMD
;
		MEM16
		IDX16
		REP	#00110000B	; memory,index 16bit mode
;
		LDA	>BKWD2130
		STA	<WD2130
;
		LDA	>BKSCH1
		STA	<SCCH1
		LDA	>BKSCH2
		STA	<SCCH2
		LDA	>BKSCV1
		STA	<SCCV1
		LDA	>BKSCV2
		STA	<SCCV2		; SCCH,V pull
		STZ	<SCCH3
		STZ	<SCCV3
;
		LDA	>BKYRXD
		STA	!YUREXD
		LDA	>BKYRYD
		STA	!YUREYD
;
		MEM8
		IDX8
		SEP	#00110000B	; memory,index 8bit mode
;
		INC	<CGVMAF
MPDP980		EQU	$
		RTL
;
;
;
;---------------------------------------; fade in
MPDPC00		EQU	$
		JSL	>LGTWPMV	; light wipe
;
		INC	<BLKFLG
		LDA	<BLKFLG
		CMP	#00FH
		BNE	MPDPC40		; fade in end ?
;					; yes
		LDA	!NXSLMD
		STA	<SLMODE
		STZ	<GAMEMD
		STZ	!MAPDMD
		STZ	<JRSBPT
		LDA	#00FH
		STA	<BLKFLG		; blanking off
;
		LDA	>BKWD420C
		STA	<WD420C
MPDPC40		EQU	$
		RTL
;
;
;
;
;
;
;
;
;
;
		END