     			extend
;-----------------------------------------------------
			include		../join/rp5c77
			include		../join/buffer.def
			include		../join/rp5a22
			include     ../join/work.def
			include		../join/label.def
			include		../join/object.def
;-----------------------------------------------------
			glb			Staff_roll_A,Staff_roll_B
;
			ext			Y_set
;----------------------------------------------------
Display_timer	equ		1a00h
;---------------------------------
Counter_cmp		equ		1a02h
End_cmp			equ		1a06h
Erase_end_counter	equ		1a08h
Obj_check_flag	equ		1a0ah
Move_limit_cmp	equ		1a0ch
Move_counter	equ		1a0eh
Start_counter	equ		1a10h
Pack_end_flag	equ		1a12h
;----------------------------------
Name_counter_cmp	equ		1a14h
Name_End_cmp		equ		1a1ah
Name_move_limit_cmp	equ		1a20h
Name_Move_counter	equ		1a26h
Name_Start_counter	equ		1a2ch
Person_cmp			equ		1a32h
Person_end_flag		equ		1a38h
Name_counter_cmp2	equ		1a3eh
Person_counter		equ		1a40h
NameErase_counter	equ		1a42h
Position_cmp		equ		1a52h
Start_position		equ		1a54h
All_end_set			equ		1a56h
;
Width_add			equ		1a76h
No_jmp_flag			equ		1a94h
Name__acceleration	equ		1ab2h
Jump_name_set_flag	equ		1ab4h
;-----------------------------------
oamdat			equ		0h
msbdat			equ		2h
color_set		equ		4h
;
bank83			sect	rel			;(PBR=83)
;******************************************************
;				Ａ画面用文字セット
;******************************************************
Staff_roll_A	equ		$
				phb
				phk
				plb
;
				mem16
				idx16
				lda		ending_pattern
				and		#0002
				beq		owari_roll_A
				lda		ending_counter
				beq		owari_roll_A
;
				lda		#0200h
				sta		<oamdat
				lda		#0400h
				sta		<msbdat
				JSR		Staff_roll_set
;
owari_roll_A	plb
				rtl
;******************************************************
;				Ｂ画面用文字セット
;******************************************************
Staff_roll_B    equ     $
				phb
				phk
				plb
;
				mem16
				idx16
				lda		ending_pattern
				and		#0002
				bne		owari_roll_B
				lda		ending_counter
				beq		owari_roll_B
;
				lda		#0420h
				sta		<oamdat
				lda		#0620h
				sta		<msbdat
				JSR		Staff_roll_set
;
owari_roll_B	plb
				rtl
;*****************************************************
;				メインセット
;*****************************************************
Staff_roll_set	equ		$
;<<<<<<<<<<<<<<<<< イニシャルチェック >>>>>>>>>>>>>>>>
				lda		ending_counter
				cmp		#1000h
				bne		Move_set
;<<<<<<<<<<<<<<<<< イニシャルセット >>>>>>>>>>>>>>>>>
				JSR		Executive_position_set
				JSR		Name_set
				jmp		owari_display
;<<<<<<<<<<<<<<<<< 移動チェック >>>>>>>>>>>>>>>>>>>>>
Move_set		lda		Pack_end_flag
				cmp		#0002
				beq		End_name_set
				cmp		#0001
				beq		Set_move_name
;<<<<<<<<<<<<<<<<< 役職名移動セット >>>>>>>>>>>>>>>>>
				JSR		Executive_position_move
				jmp		owari_display
;<<<<<<<<<<<<<<<< 名前表示セット >>>>>>>>>>>>>>>>>>>>
Set_move_name	JSR		Name_move
				jmp     owari_display
;<<<<<<<<<<<<<<< 最終の名前特別処理 >>>>>>>>>>>>>>>>>>
End_name_set	lda		ending_pattern
				cmp		#000eh
				bne		Display_timeset
;
				lda		All_end_set
				bne		Display_timeset
;
				JSR		Jump_name_set
				jmp		owari_display
;<<<<<<<<<<<<<<< 文字表示タイマー >>>>>>>>>>>>>>>>>>>>>
Display_timeset	inc		Display_timer
				lda		Display_timer
				cmp		#00b3h
				bcc		owari_display
				cmp		#00b4h
				beq		owari_pattern
;<<<<<<<<<<<<<<<<< 文字消滅セット_2 >>>>>>>>>>>>>>>>>>
				JSR		Erase_Executive_position
				JSR		Erase_name_set
				jmp     owari_display
;<<<<<<<<<<<<<<<< 終わりの処理 >>>>>>>>>>>>>>>>>>>>>>
owari_pattern	lda		#0040h
				sta		ending_counter
owari_display	rts
;******************************************************
;				サブルーチン
;******************************************************
;
;<<<<<<<<<<<<<<<<<< 役職名のセット >>>>>>>>>>>>>>>>>>>
Executive_position_set
;---------(ＯＢＪ数コンプセット)------
				mem16
				idx16
				ldx		ending_pattern
				lda		Executive_position_counter,x
				sta		Counter_cmp
				clc
				adc		#0002
				sta		Counter_cmp+2
				lda		#0004
				sta		Move_limit_cmp
;--------------(ＭＳＢセット)-------
				ldy		#0
				lda		#05555h
loop_msb		sta		(<msbdat),y
				iny
				iny
				cpy		#0020h
				bne		loop_msb
;---------------(文字ストップ位置セット)--------
				lda		Executive_position_end,x
				sta		End_cmp
;---------------(カラーセット)----------
				ldy		#0
				lda		#3c02h
				sta		<color_set
				lda		#007eh
				sta		<color_set+2
				lda		Select_color,x
				tax
loop_color_set	lda		>color_buffer+180h,x
				sta		[<color_set],y
				inx
				inx
				iny
				iny
				cpy		#0006
				bne		loop_color_set
;------------(キャラクターデーターセット)-------
				ldx     ending_pattern
				ldy		#0002
				lda		Executive_position_data,x
				tax
loop_Executive	lda		!0,x
				sta		(<oamdat),y
				inx
				inx
				JSR     Y_set
				cpy		Counter_cmp+2
				bne		loop_Executive
;------------(スタートポジションセット)---------
Set_start_position
				ldy		#0
				ldx		ending_pattern
				lda		Executive_position_Start_position,x
loop_position	sta		(<oamdat),y
				JSR     Y_set
				cpy		Counter_cmp
				bne		loop_position
				rts
;
Select_color	DW		0002h,000ah,0012h,001ah
				DW		0002h,000ah,0012h,001ah
;<<<<<<<<<<<<<<<<<<< 役職名を動かす >>>>>>>>>>>>>>>>>>
Executive_position_move
;--------------(移動セット)----------------
				mem8
				sep		#00100000b
				ldy		Start_counter
loop_move_set	lda		(<oamdat),y
				cmp		End_cmp
				beq		Pack_set
				clc
				adc		#0004
				sta		(<oamdat),y
;
				bcc		Set_next
				JSR		OBJ_ERASE
;
Set_next		JSR     Y_set
				cpy		Move_limit_cmp
				bne		loop_move_set
;---------(文字間隔を開けるためのカウンターセット)------
				lda		Move_counter		
				cmp		#1ch
				beq		Set_count
				clc
				adc		#04
				sta		Move_counter
End_move		mem16
				rep		#00100000b
				rts
;------(止まった文字の処理を外す。止まる位置を変える)-----
Pack_set		mem8
				lda		Start_counter
				clc
				adc		#04
				cmp		Move_limit_cmp
				beq		End_pack
				sta		Start_counter
;
				lda		End_cmp
				sec
				sbc		#08
				sta		End_cmp
				jmp		Set_next
;-------(処理を辞めるフラグを立てる)----------
End_pack		lda		#01
				sta		Pack_end_flag
				stz		Start_counter
				jmp		End_move
;----(文字間隔が開いた次の文字を動かすセット)---------
Set_count		mem8
				stz		Move_counter
				lda		Move_limit_cmp
				cmp		Counter_cmp
				beq		End_move
				clc
				adc		#04
				sta		Move_limit_cmp
				jmp		End_move
;<<<<<<<<<<<<<<<<< 役職名を消す >>>>>>>>>>>>>>>>>>>>>>
Erase_Executive_position
;-----------(処理を止めるカウンタチェック)-------
				mem16
				lda		Erase_end_counter
				cmp		#0040h
				beq		End_erase
				mem8
				sep		#00100000b
;---------(移動セット)-----------
				stz		Obj_check_flag
				ldy		Start_counter
loop_erase_set	lda		(<oamdat),y
				clc
				adc		#04
				sta		(<oamdat),y
;
				bcc		next_erase
				JSR		OBJ_ERASE
;
next_erase		JSR     Y_set
				cpy		Counter_cmp
				bne		loop_erase_set
				inc		Erase_end_counter
End_erase		mem16
				rep		#00100000b
				rts
;<<<<<<<<<<<<<<<<<< 名前のセット >>>>>>>>>>>>>>>>>>>
Name_set		equ		$
;------(ネーム数コンプ,ループコンプ,スタートアドレス)---
				mem16
				idx16
				lda		#0058h
				sta		Name_move_limit_cmp
				lda		#0050h
				sta		Name_Start_counter
;
				ldx		ending_pattern
				lda		Select_Name_counter,x
				tax
;
				lda		!0,x
				sta		Name_counter_cmp
				sta		Name_Start_counter+2
				clc
				adc		#0008
				sta		Name_move_limit_cmp+2
;
				lda		!2,x
				sta		Name_counter_cmp+2
				sta		Name_Start_counter+4
				clc
				adc		#0008
				sta		Name_move_limit_cmp+4
;
				lda		!4,x
				sta		Name_counter_cmp+4
				clc
				adc		#0002
				sta	   Name_counter_cmp2
;------(文字ストップ位置)----------
				ldx     ending_pattern
				lda		Name_end_data,x
				sta		Name_End_cmp
				sta		Name_End_cmp+2
				sta		Name_End_cmp+4
;-------(人数セット)-------------
				lda		Select_peson_set,x
				sta		Person_cmp
				lda		#0fc00h
				sta		Name__acceleration
;-------(キャラクタデーターセット)---------
				ldx     ending_pattern
				ldy		#0052h
				lda		Name_data,x
				tax
loop_1person	JSR		Name_character_set
				cpy		Name_counter_cmp2
				bne		loop_1person
;------(スタートポジションセット)-----------
				ldx		ending_pattern
				lda		Name_Start_position,x
				sta		Start_position
				ldx		#0
loop_position_1	lda		Name_counter_cmp,x
				sta		Position_cmp
;
				lda		Name_Start_counter,x
				tay
				lda		Start_position
loop_position2	JSR		Set_name_position
				cpy		Position_cmp
				bne		loop_position2
				sec		
				sbc		#1800h
				clc
				adc		#0010h
				sta		Start_position
				inx
				inx
				cpx		Person_cmp
				bne		loop_position_1
				rts
;<<<<<<<<<<<<<<<<<<< 名前を動かす >>>>>>>>>>>>>>>>>>
Name_move		equ		$
				mem16
				ldx		#0
loop_name_sub	JSR		Move_name_sub
				inx
				inx
				cpx		Person_cmp
				bne		loop_name_sub
;----(紺野さんの名前セット)--------
				lda     Person_end_flag
				lda		ending_pattern
				cmp		#000eh
				bne		Ceck_person
				lda     Person_end_flag
				beq		Ceck_person
				JSR		Set_konno
;-------(人数チェック)-----------
Ceck_person		lda		Person_counter
				cmp		Person_cmp
				bne		owari_name_sub
				lda		#0002
				sta		Pack_end_flag
owari_name_sub	rts
;<<<<<<<<<<<<<<<< 名前を動かすルーチン >>>>>>>>>>>>>
Move_name_sub	equ		$
				mem16
;-------(処理を辞めるチェック)---------
				lda		Person_end_flag,x
				bne		End_move_1
;-----------(移動セット)----------------
				lda		Name_Start_counter,x
				tay
loop_move_set1	mem8
				sep		#00100000b
				lda		(<oamdat),y
				sec
				sbc		#0004
				sta		(<oamdat),y
				bcs		Set_next_under
;
				phx
				JSR		OBJ_ERASE
				plx
;
Set_next_under	JSR     Y_set
				lda		(<oamdat),y
				sec
				sbc		#0004
				sta		(<oamdat),y
				pha
				bcs		Check_stop
				phx
				JSR		OBJ_ERASE
				plx
;------(文字のストップ位置かどうかのチェック)---------
Check_stop		pla
				cmp		Name_End_cmp,x
				beq		Pack_set_1
;
Set_next_1		mem16
				rep		#00100000b
				JSR     Y_set
				tya
				cmp		Name_move_limit_cmp,x
				bne		loop_move_set1
;--------(文字間隔を開けるためのカウンター)--------
				lda		Name_Move_counter,x		
				cmp		#001ch
				beq		Set_count_1
				clc
				adc		#0004
				sta		Name_Move_counter,x
End_move_1		rts
;-----(止まった文字の処理を外す)------
Pack_set_1		mem16
				rep		#00100000b
;		
				lda		Name_Start_counter,x
				clc
				adc		#0008
				cmp		Name_counter_cmp,x
				beq		End_pack_1
				sta		Name_Start_counter,x
;-----(杉山さんの名前を圧縮)------------
				cpx		#0002
				bne		Add_end
				lda		ending_pattern
				cmp		#000eh
				beq		Set_next_1
;--------(止まる位置の変更)------
Add_end			lda		Name_End_cmp,x
				clc
				adc		#0008
				sta		Name_End_cmp,x
				jmp		Set_next_1
;---------------(終了セット)-----------------------
End_pack_1		mem16
				rep		#00100000b
;		
				inc		Person_end_flag,x
				inc		Person_counter
				inc     Person_counter
				jmp		End_move
;---(文字間隔が空いた時、次の文字の移動セット)------
Set_count_1		mem16
				rep		#00100000b
;
				stz		Name_Move_counter,x
				lda		Name_move_limit_cmp,x
				cmp		Name_counter_cmp,x
				beq		End_move_1
				clc
				adc		#0008
				sta		Name_move_limit_cmp,x
				jmp		End_move_1
;<<<<<<<<<<<<<<<<< 名前を消す >>>>>>>>>>>>>>>>>>>>>>
Erase_name_set	equ		$
				lda		NameErase_counter
				cmp		#0040h
				beq		End_erase_1

				mem8
				sep		#00100000b
;
				ldy		#0050h
loop_erase_set1	JSR		NAME_MOVE
				cpy		Name_counter_cmp+4
				bne		loop_erase_set1
;
				mem16
				rep		#00100000b
				inc		NameErase_counter
End_erase_1		rts
;
NAME_MOVE		equ		$
				mem8
				lda		(<oamdat),y
				sec
				sbc		#04
				sta		(<oamdat),y
				bcs		Set_erase_under
				JSR		OBJ_ERASE

;
Set_erase_under	JSR     Y_set
				lda		(<oamdat),y
				sec
				sbc		#04
				sta		(<oamdat),y
				bcs		next_erase_1
				JSR		OBJ_ERASE
;
next_erase_1	JSR     Y_set
				rts
;<<<<<<<<<<<<<<<< 紺野さん用ルーチン >>>>>>>>>>>>>>>>>
Set_konno		mem8
				sep		#00100000b
				ldy     #0058h
				lda     (<oamdat),y
				cmp		#70h
				beq		Set_O
				ldy		#0058h
loop_pack		JSR     NAME_MOVE
				cpy		#00c0h
				bne		loop_pack
;
Set_O			ldy		#0050h
				JSR     NAME_MOVE
				ldy		#0050h
				lda     (<oamdat),y
				cmp		#0f0h
				bne		owari_konno
				ldy		#0051h
				lda		#0e0h
				sta     (<oamdat),y
				ldy		#0055h
				sta		(<oamdat),y
owari_konno		mem16
				rep		#00100000b
				rts
;<<<<<<<<<<<<<<<<<< 杉山さん用ルーチン >>>>>>>>>>>>>>>
Jump_name_set	equ		$
;-------------(加速度セット)--------------
				ldx		#0
				mem16
				rep		#00100000b
				lda		Name__acceleration
				cmp		#0400h
				beq		max_speed_1
Set_kasoku_1	clc
				adc		#0080h
				sta		Name__acceleration	
;---------------(移動セット)--------------
max_speed_1		ldy		#00c8h
loop_jmp		lda		No_jmp_flag,x			
				beq		jump_set
				JSR		Y_set
				JSR     Y_set
				cpx		#001ch
				bne		No_jump_set			
				inc		All_end_set
				jmp		No_jump_set			
jump_set		JSR		Set_one_jmp
No_jump_set
				inx
				inx
				cpx		#001eh
				bne		loop_jmp
				mem16
				rep		#00100000b
				rts
;

Select_Width_jmp
				DW		0072h,00e4h,0156h,01c8h
				DW		0239h,02abh,031dh,038fh
				DW		0401h,0472h,04e4h,0556h
				DW		05c8h,0639h,06abh
Set_one_jmp		equ		$
;--------------(移動サブルーチン)-------------
				mem8
				sep		#00100000b
				lda		Width_add,x				;横方向移動量セット
				clc
				adc		Select_Width_jmp,x
				sta		Width_add,x
				lda		Select_Width_jmp+1,x
				adc		#0
				sta		Width_add+1,x
;
				iny
				lda		(<oamdat),y				;降下セット
				clc
				adc		Name__acceleration+1
				cmp		#34h
				beq		No_jmp
				sta		(<oamdat),y
				dey
				lda		(<oamdat),y				;横方向セット
				clc
				adc		Width_add+1,x
				sta		(<oamdat),y
				JSR		Y_set
;
				lda		(<oamdat),y				;横方向セット
				clc
				adc		Width_add+1,x
				sta		(<oamdat),y

				iny
				lda		(<oamdat),y				;降下セット
				clc
				adc		Name__acceleration+1
				sta		(<oamdat),y
				dey
				JSR		Y_set
				rts
;
No_jmp			inc		No_jmp_flag,x			;ストップフラグセット
				dey
				JSR		Y_set
				JSR     Y_set
				rts
;<<<<<<<<<<<<<<<<<< ＭＳＢセット >>>>>>>>>>>>>>>>>>>>>
OBJ_ERASE		equ		$
				mem16
				idx16
				rep		#00110000b
				phy
				tya
				and		#000ch					;何個目のオブジェチェック
				lsr		a
				lsr		a
				tax
;
				tya								;何個目のMSBチェック
				lsr		a
				lsr     a
				lsr     a
				lsr     a
				tay
;
				mem8
				sep		#00100000b
				lda		(<msbdat),y				;MSBセットチェック
				and		MSB_data,x
				bne		Set_MSB1
;
				lda     (<msbdat),y				;MSB裏画面セット
				ora		MSB_data,x
				sta		(<msbdat),y
				ply
owari_erase		rts
;
Set_MSB1		idx16							;ＭＳＢおもて画面の時
				mem8
				lda     (<msbdat),y
				and		MSB_data1,x
				sta		(<msbdat),y
				ply
				jmp		owari_erase
MSB_data		DB		01h,04h,10h,40h
MSB_data1		DB		0feh,0fbh,0efh,0bfh
;
Set_name_position
				mem16
				pha
				sta		(<oamdat),y
				JSR     Y_set
				clc
				adc		#0800h
				sta     (<oamdat),y
				JSR     Y_set
				pla
				rts
;
Name_character_set
				mem16
loop_name_set	lda		!0,x
				sta		(<oamdat),y
				JSR     Y_set
				cmp		#0ab0h
				beq		No_inc_set
				inc		a
No_inc_set		sta		(<oamdat),y
				JSR     Y_set
				inx
				inx
				rts
;**************************************************************
;					データ
;**************************************************************
;
;<<<<<<<<<<<<<<<<<< 役職名データー >>>>>>>>>>>>>>>>>>>>
;
Executive_position_data						;キャラクターデーター
				DW		Executive_produser,Produser
				DW		Programmer,Designer,Composer
				DW		Illustrator,Editor,Director
Executive_produser
				DW		0868h,0860h,0862h,0863h,086ah
				DW		0869h,0868h,0867h,08b0h,0860h
				DW		0866h,0865h,0864h,0863h,0862h
				DW		0860h,0861h,0860h
;
Produser		DW		0868h,0860h,0862h,0863h,086ah
				DW      0869h,0868h,0867h
;
Programmer		DW		086eh,0868h,0860h,086dh,086dh
				DW		086ch,0868h,086bh,0869h,0868h
				DW		0867h
;
Designer		DW		086eh,0868h,0860h,0870h,086bh
				DW		0865h,086eh,0860h,086ah,086fh
				DW		086bh,086fh,0862h
;
Composer		DW		086eh,0868h,0860h,086eh,0869h
				DW		0867h,086dh,0869h,0862h,08b0h
				DW		086ah,0870h,0863h,0869h,086eh
;
Illustrator		DW		086eh,0868h,0869h,0864h,086ch
				DW		0868h,0864h,086eh,0863h,0871h
				DW		0871h,0865h
;
Editor			DW		0868h,0869h,0864h,0865h,086ah
				DW		0860h,08b0h,0871h,086ch,0863h
				DW		0870h,086ch,086dh
;
Director		DW		086eh,0868h,0869h,0864h,0862h
				DW		0860h,0868h,0865h,086ah		
;
Executive_position_counter						;obj数*04h
				DW		0048h,0020h,002ch,0034h,003ch
				DW		0030h,0034h,0024h
;
Executive_position_end							;ストップポジション
				DW		0098h,0048h,0060h,0070h,0080h
				DW		0068h,0070h,0050h
;
Executive_position_Start_position				;スタートポジション
				DW		80f8h,10f8h,80f8h,10f8h,80f8h
				DW		10f8h,80f8h,10f8h
;
;<<<<<<<<<<<<<<<<<<< 名前データー >>>>>>>>>>>>>>>>>>>>>>>>
;
Name_data		DW		President_name,Producer_name
				DW		Programmer_name,Designer_name
				DW		Composer_name,Illustrator_name
				DW		Editor_name,Director_name
;
President_name	DW		0a82h,0a74h,0a96h,0a7ah,0a80h 		;社長
				DW		0a82h,0a74h,0ab0h,0a94h,0a72h
				DW		0a92h,0a72h,0a76h,0a8ah,0a82h
				DW		0a74h
;
Producer_name	DW		0a80h,0a82h,0a74h,0a7eh,0a78h		;宮本さん
				DW		0a96h,0a76h,0ab0h,0a92h,0a74h
				DW		0a94h,0a72h,0a92h,0a7ah,0a88h
				DW		0a7ah		
;
Programmer_name	DW		0a7ch,0a78h,0a8eh,0a84h,0a74h		;自分
				DW		0ab0h,0a94h,0a72h,0a92h,0a72h
				DW		0a92h,0a7ah,0a88h,0a7ah
;
				DW		0a82h,0a72h,0a84h,0a74h,0a92h		;矢島さん
				DW		0a78h,0ab0h,0a94h,0a72h,0a84h
				DW		0a74h,0a92h,0a72h
;
				DW		0a92h,0a72h,0a80h,0a72h,0a88h		;木村さん
				DW		0a7ah,0ab0h,0a7ch,0a74h,0a92h
				DW		0a76h,0a96h,0a72h
;
Designer_name	DW		0a8eh,0a72h,0a7ah,0a7ch,0a74h		;森さん
				DW		0ab0h,0a92h,0a7ah,0a96h,0a74h
;
				DW		0a88h,0a72h,0a8ch,0a72h,0a80h		;杉山さん
				DW		0a82h,0a74h,0ab0h,0a80h,0a76h
				DW		0a7eh,0a74h,0a94h,0a72h,0a92h
				DW		0a72h
;
Composer_name	DW		0a88h,0a72h,0a96h,0a7ah,0ab0h		;坂東さん
				DW		0a90h,0a72h,0a8eh,0a8ch,0a7ah
;
				DW		0a80h,0a7ah,0a94h,0a7ah,0ab0h		;岡さん
				DW		0a7ah,0a7ch,0a72h
;
Illustrator_name
				DW		0a94h,0a7ah,0a80h,0a82h,0a74h		;小田部さん
				DW		0a72h,0a7ch,0a74h,0ab0h,0a7ch
				DW		0a7ah,0a74h,0a86h,0a76h,0a92h
				DW		0a74h
;
				DW		0a92h,0a74h,0a78h,0ab0h,0a94h		;吉村さん
				DW		0a7ah,0a80h,0a82h,0a74h,0a92h
				DW		0a76h,0a96h,0a72h
;
				DW		0a94h,0a7ah,0a74h,0a8ah,0a82h		;;小泉さん
				DW		0a74h,0ab0h,0a7ch,0a7ah,0a88h
				DW		0a72h,0a90h,0a78h
;
Editor_name		DW		0a72h,0a88h,0a80h,0a76h,0a80h,0a82h		;手島さん
				DW		0a74h,0ab0h,0a88h,0a78h,0a84h
				DW		0a74h,0a92h,0a72h
;
Director_name	DW		0a7ah,0a82h,0a74h,0a8ch,0a78h,0a98h		;紺野さん
				DW		0a76h,0a74h,0ab0h,0a7ch,0a7ah
				DW		0a8eh,0a8eh,0a7ah
;
				DW		0a88h,0a72h,0a8ch,0a72h,0a80h		;杉山さん
				DW		0a82h,0a74h,0ab0h,0a80h,0a76h
				DW		0a7eh,0a74h,0a94h,0a72h,0a92h
				DW		0a72h
;
Select_Name_counter
				DW		Name_counter1,Name_counter1,Name_counter3
				DW		Name_counter4,Name_counter5,Name_counter6
				DW		Name_counter7,Name_counter8
Name_counter1	DW		00d0h,00d0h,00d0h					;１つのobj数
Name_counter3	DW		00c0h,0128h,0190h
Name_counter4	DW		00a0h,0120h,0120h
Name_counter5	DW		00a0h,00e0h,00e0h
Name_counter6	DW		00d0h,0138h,01a0h
Name_counter7	DW		00c0h,00c0h,00c0h
Name_counter8	DW		00c0h,0140h,0140h
;
Name_end_data	DW		0070h,0070h,0080h,0070h					;文字ストップ位置
				DW		00a0h,0070h,0080h,0070h
;
Name_Start_position
				DW		0a800h,3800h,0c000h,4800h
				DW		0b800h,5000h,0a800h,4800h
;															;表示人数*2
Select_peson_set
				DW		0002h,0002h,0006h,0004h
				DW		0004h,0006h,0002h,0004h
				END

