;*********************************************************************
;*								*
;*	------------------------				*
;*		STARFOX2 					*
;*	------------------------				*
;*								*
;*	File 		: continue.asm				*
;* 	Description	: Continue SEQ				*
;*	Date		: 1994.7.15				*
;*	Author		: H.Yajima				*
;*								*
;*********************************************************************
;
;
;
;
;---------------------------------------------------------------------
	INCPUB  continue
;---------------------------------------------------------------------
;
;
;
;
;
;------------------------------------------------------------
temp1	equ	Xwork6	; library work
temp2	equ	Xwork7	; library work
;------------------------------------------------------------
;
;
;
;
;
;
;
;*******************************************************************
;	continue
;*******************************************************************
	longi
	shorta
;------------------------------------------------------------
continue_l
	php
	phb
	phk
	plb
;-------------------------------------------
	ai16
	jsr	init_continue
	jsr	InitScreen
;-------------------------------------------
.loop	a8
	lda	#iv_titleirq
	sta	trans_flag
	km_waittrans

	jsl	do_sprites_l

	ai16
	jsr	main_continue

	lda	trig0
	and	#button_start+button_A+button_B
	beq	.loop

;-------------------------------------------

	a8

	lda	continue_status
	bne	.title	
	dec	kw_continue1
	km_setgamemode	selectmissionplayer
	bra	.exit
.title	km_setgamemode	title

;-------------------------------------------
.exit	km_screenoff
	plb
	plp
	rtl
;*******************************************************************
	longi
	longa
;*******************************************************************
;	initialize
;*******************************************************************
init_continue
	stz	continue_status

	ldy	#cont_data&0ffffh
	jsl	Init_OBJ
	rts

;*******************************************************************
;	main
;*******************************************************************
main_continue

	stz	sprite_register
	stz	sprite_start


	jsl	Main_OBJ
	

	ldx	#continue_status
	lda	#2
	jsr	Moveupdown


	Mmessage 58h,90h
	db	_c,_o,_n,_t,_i,_n,_u,_e,ed
	Mmessage 74h,0a0h
	db	_y,_e,_s,ed
	Mmessage 78h,0aah
	db	_n,_o,ed

	lda	kw_continue1
	and	#00ffh
	Mdispdigit 0a0h,90h

	lda	continue_status
	asl	a
	tax
	ldy	positiondata&0ffffh,x
	lda	#3025h	
	jsl	OBJ_set

	rts

positiondata	db	68h,0a0h
	db	68h,0aah

;***********************************************************************
;	Continue Objects
;***********************************************************************

cont_data
;----------------------------------------------------------
	dl		SEQ_d2_0
	M2dOBJdata	contprog,0h,080h,050h,0h,0h,0
	Mdataend
;----------------------------------------------------------

contprog
	phk
	plb
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
	jsl	SetOAM
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
	rtl
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 


;***********************************************************************
;	Move Cursor
;***********************************************************************
;
; A register = MAX parameter
; X register = 0bank-RAM address
;
;-----------------------------------------------------------------------
Moveupdown	dec	a
	sta	temp1
	ldy	0,x
	lda	trig0
	bit	#button_up+button_down
	beq	.exit
	bit	#button_up
	beq	.down
	dey
	bmi	.exit
	bpl	.set
.down	iny
	cpy	temp1
	bcc	.set
	ldy	temp1
.set	sty	0,x
.exit	rts

;============================================================
	end